nerf/nixConfig
1
0
Fork 0
forked from Fachschaft/nixConfig
Code Pull requests Activity

populate ip address based on hostname and populate the hostfile with other vm ips

Browse source
This commit is contained in:
Dennis Frieberg 2025-03-31 02:28:53 +02:00
parent a6db8ef50f
commit d5302456bb
Signed by: nerf
SSH key fingerprint: SHA256:zvrU0EwwaNK65M+AqL9IOTRawFq0JZ8QXBASxxGpxmg
7 changed files with 87 additions and 8 deletions
Download patch file Download diff file Expand all files Collapse all files

32
nixos/roles/vmNetwork.nix Normal file
View file

@ -0,0 +1,32 @@
{
lib,
config,
...
}: let
inherit (lib) lists mapAttrsToList;
inherit (lib.attrsets) foldAttrs concatMapAttrs;
inherit (lib.asserts) assertMsg;
inherit (builtins) elem;
hostmap = import ./hostmap.nix;
myhostName = config.networking.hostName;
# We replace our own ip with 127.0.0.1 in /etc/hosts
# To turn the hostmap around suitable for networking.hosts the following simple code almost works
# concatMapAttrs (hostname: ipData: { ${ipData.ipv4} = [hostname]; }) hostmap
# but breaks as soon as we want to map two different names to the same ip.
# So the code looks uglier than one would expect.
globalhosts = foldAttrs (a: b: a ++ b) [] (mapAttrsToList (hostname: ipData: {${ipData.ipv4} = [hostname];}) hostmap);
myhosts = concatMapAttrs (ip: hosts:
if (elem myhostName hosts)
# nixos maps the hostname to the loopback 127.0.0.2 by default, so we exclude it here.
# there is also a default localhost to 127.0.0.1 in place
then {"127.0.0.1" = lists.filter (x: x != myhostName) hosts;}
else {${ip} = hosts;})
globalhosts;
myIp = assert (assertMsg (hostmap ? ${myhostName}.ipv4) "${myhostName} has no ip configured in nixos/roles/hostmap.nix"); hostmap.${myhostName}.ipv4;
in {
imports = [
../modules/vmNetwork.nix
];
networking.hosts = myhosts;
vmNetwork.ipv4 = myIp;
}